'Checks if either the Login or the Main window is already open
Function appNotOpen()
    appNotOpen = true
    If Dialog("Login").Exist(0) or Window("Flight Reservation").Exist(0) Then
        appNotOpen = false
    End If
End Function

'Opens the application if not already open
Function openApp()
    If appNotOpen() Then
        SystemUtil.Run "C:\Program Files\HP\Unified Functional Testing\samples\flight\app\flight4a.exe","","C:\Program Files\HP\Unified Functional Testing\samples\flight\app\",""
        openApp = Dialog("Login").WaitProperty("enabled", 1, 5000)
    else
        openApp = true
    End If    
End function

'Handles the Login dialog: Enters the Agent Name and the Password and clicks on the OK button
Function login(agentName, password, button)
    with Dialog("Login")
        .WinEdit("Agent Name").Set agentName 
        .WinEdit("Password").SetSecure password
        .WinButton(button).Click
        If .exist(0) Then
            login = false
        else
            login = true
        End If
    end with
End Function

'Performs a standard checkpoint on a message open by the FR application
Function checkMessage(id)
    If Dialog("Login").Dialog("Flight Reservations").Exist(0) Then    
        checkMessage = Dialog("Login").Dialog("Flight Reservations").Static("Message").Check(CheckPoint("Message"&id))
        Dialog("Login").Dialog("Flight Reservations").WinButton("OK").Click
    else
        checkMessage = false
    End if
End Function

'Performs several standard checkpoints on the Main window and on several of its child objects
'to verify its initial state
function verifyMainWndInitialState()
    with Window("Flight Reservation")
        if .Check(CheckPoint("Flight Reservation")) then
            .WinButton("FLIGHT").Check CheckPoint("FLIGHT")
            .WinRadioButton("First").Check CheckPoint("First")
            .WinButton("Update Order").Check CheckPoint("Update Order")
            .WinButton("Delete Order").Check CheckPoint("Delete Order")
            .WinButton("Insert Order").Check CheckPoint("Insert Order")
        End if
    end with
End function

'Variables declaration and initialization
Dim agentName, password, button

agentName = DataTable("AgentName", dtLocalSheet)
password = DataTable("Password", dtLocalSheet)
button = DataTable("Button", dtLocalSheet)

'Tries to open the application
If not openApp() Then
    ExitTest        
End If 

'Tries to login with the input data
if not login(agentName, password, button) Then
    'Checks if a warning/error message opened, if it's correct in context and closes it
    if checkMessage("1") then 
        'Checks if a second warning/error message opened, if it's correct in context and closes it
        if checkMessage("2") then 
            If not Dialog("Login").Exist(0) Then
                reporter.ReportEvent micPass, "Login", "Maximum number of trials exceeded. Application closed."
                'If a second message opened, then the number of login trials was exceeded and the application closed, so we need to reopen the application
                call openApp() 
            End If            
        End if    
    End If 
else
    call verifyMainWndInitialState()
End if 'Tries to login